"Name"    = 'Archetype Query Language (AQL) - {Equal}'
"Version" = '0.5'
"Date"	   = '02 July 2008'
"Author"  = 'Chunlan Ma & Heath Frankel'
"About"   = 'Ocean Informatics'


! Gramma Configuration

"Case Sensitive" = 'False'
"Start Symbol"   = <Query>

! =============================================================================
! Comments
! =============================================================================

Comment Start = '/*'
Comment End   = '*/'
Comment Line  = '!'

! Character Set Definitions

{quote} = ['']
{String Char} = {Printable} - ["] - {quote}
{Hex Char} = {Digit} + [ABCDEF]
{NonZeroDigit} = {Digit} - [0]

{LetterMinusA} = {Letter} - [aA]
{LetterMinusT} = {Letter} - [tT]
!{AlphanumericMinusT} = {Alphanumeric} - [t]
!{NonZeroAlphanumeric} = {Alphanumeric} - [0]
{IdChar} = {Alphanumeric} + [_] - [.]   ! not allowing a dot
{IdCharMinusT} = {IdChar} - [tT]

! Terminal Definitions

!Identifier  = {Letter}({Alphanumeric}|'_')*   ! Conflicts with UID
!Identifier  = {Letter}{IdChar}*   ! Conflicts with extended NodeId 
! restricted to allow only letters after the 4th character due to conflict with extended NodeId
!Identifier  = {Letter}{IdChar}?{IdChar}?{IdChar}?({Letter}|'_')*  !Conficts with NodeId which may have any length of digit, such as at0.9
Identifier = {LetterMinusA}{IdCharMinusT}?{IdChar}* | 'a''t'?(({letter}|'_')*|{LetterMinusT}{Alphanumeric}*)  
	
String      = '"'{String Char}*'"'
            | ''{String Char}*''
Integer     = {Digit}+
Float       = {Digit}+'.'{Digit}+
Date        = ''{Digit}{Digit}{Digit}{Digit}'-'{Digit}{Digit}'-'{Digit}{Digit}''
Boolean     = 'true' | 'false'

!NodeId      = 'a''t'{Digit}{Digit}{Digit}{Digit}
! conflict with Identifier
!NodeId	     = 'at'({Digit}{Digit}{Digit}{Digit}('.0'*('.'{NonZeroDigit}{Digit}*)+|('.'{NonZeroDigit}{Digit}*)*)|'0''.0'*('.'{NonZeroDigit}{Digit}*)+|('.'{NonZeroDigit}{Digit}*)+)
NodeId	     = 'at'({Digit}+('.'{Digit}+)*) 

!Parameter   = '$'{letter}({Alphanumeric}|'_')*
Parameter   = '$'{letter}{IdChar}*

! could constrain UID further
UniqueId    = {digit}+('.'{digit}+)+'.'{digit}+  ! OID
            | {Hex Char}+('-'{Hex Char}+)+       ! UUID

! could constrain ArchetypeId further
!ArchetypeId = {Letter}+'-'{Letter}+'-'({Letter}|'_')+'.'({Letter}|'_'|'-')+'.v'{Digit}+('.'{Digit}+)?  ! not allow a number in archetype id concept, such as openEHR-EHR-OBSERVATION.laboratory-hba1c.v1 
ArchetypeId = {Letter}+'-'{Letter}+'-'({Letter}|'_')+'.'({IdChar}|'-')+'.v'{Digit}+('.'{Digit}+)?
ComparableOperator = '=' | '!=' | '>' | '>=' | '<' | '<='


! Rule Definitions
<Query> ::= <Select> <From>
            | <Select> <From> <Where>
            | <Select> <From> <OrderBy>   ! is this allowed?
            | <Select> <From> <Where> <OrderBy>
            
<Select> ::= 'SELECT' <SelectExpr>
         | 'SELECT' <TOP> <SelectExpr>

<Top> ::= 'TOP' Integer
          | 'TOP' Integer 'BACKWARD'
          | 'TOP' Integer 'FORWARD'
          
<Where> ::= 'WHERE' <IdentifiedExpr>

<OrderBy> ::= 'ORDER BY' <OrderBySeq>
<OrderBySeq>  ::= <OrderByExpr> 
		| <OrderByExpr> ',' <OrderBySeq>

<OrderByExpr> ::= <IdentifiedPath>
		| <IdentifiedPath> 'DESCENDING'
		| <IdentifiedPath> 'ASCENDING'
		| <IdentifiedPath> 'DESC'
		| <IdentifiedPath> 'ASC'

<SelectExpr> ::= <IdentifiedPathSeq>

! When multiple paths provided, each IdentifiedPath must represent an object of type DataValue
<IdentifiedPathSeq> ::= <IdentifiedPath>
			| <IdentifiedPath> 'as' Identifier
			| <IdentifiedPath> ',' <IdentifiedPathSeq>
			| <IdentifiedPath> 'as' Identifier ',' <IdentifiedPathSeq>

<From> ::= 'FROM' <FromEHR>
       | 'FROM' <FromEHR> <ContainsExpr>
       | 'FROM' <ContainsOr>
       
<FromEHR> ::= 'EHR' <StandardPredicate>
          | 'EHR' Identifier <StandardPredicate>

          
<IdentifiedExpr> ::= <IdentifiedOr>
<IdentifiedOr> ::= <IdentifiedAnd>
                 | <IdentifiedOr> 'OR' <IdentifiedAnd>
<IdentifiedAnd> ::= <IdentifiedEquality>
                 | <IdentifiedAnd> 'AND' <IdentifiedEquality>

!<IdentifiedEquality> ::= <IdentifiedRelationalExpr>
!                 | <IdentifiedOperand> '=' <IdentifiedOperand>
!                 | <IdentifiedOperand> '!=' <IdentifiedOperand>
                 
!<IdentifiedRelationalExpr> ::= <IdentifiedOperand> '<' <IdentifiedOperand>
!                 | <IdentifiedOperand> '<=' <IdentifiedOperand>
!                 | <IdentifiedOperand> '>' <IdentifiedOperand>
!                 | <IdentifiedOperand> '>=' <IdentifiedOperand>
<IdentifiedEquality> ::= <IdentifiedOperand> ComparableOperator <IdentifiedOperand>


<IdentifiedOperand> ::= <Operand> | <IdentifiedPath>

<IdentifiedPath>::= Identifier
                    | Identifier <Predicate>
                    | Identifier '/' <ObjectPath>
                    | Identifier <Predicate> '/' <ObjectPath>

<Predicate> ::= <NodePredicate>
!            | <ArchetypePredicate>
!            | <StandardPredicate>
            
!<NodePredicate> ::= '[' NodeId ']'
<NodePredicate> ::= '['<NodePredicateOr>']'

<NodePredicateOr> ::= <NodePredicateAnd>
                 | <NodePredicateOr> 'or' <NodePredicateAnd>
<NodePredicateAnd> ::= <NodePredicateComparable>
                 | <NodePredicateAnd> 'and' <NodePredicateComparable>

<NodePredicateComparable> ::= <PredicateOperand> ComparableOperator <PredicateOperand>
                          | NodeId
                          | NodeId ',' String        ! <NodeId> and name/value = <String> shortcut
                          | NodeId ',' parameter     ! <NodeId> and name/value = <Parameter> shortcut
                          
<ArchetypePredicate> ::= '[' ArchetypeId ']'
			 | '[' Parameter ']'
			 
<VersionPredicate> ::= '[' <VersionPredicateOptions> ']'
<VersionPredicateOptions> ::= 'latest_version' | 'all_versions'

<StandardPredicate> ::= '[' <PredicateExpr> ']'
<PredicateExpr> ::= <PredicateOr>
<PredicateOr> ::= <PredicateAnd>
                 | <PredicateOr> 'or' <PredicateAnd>
<PredicateAnd> ::= <PredicateEquality>
                 | <PredicateAnd> 'and' <PredicateEquality>

!<PredicateEquality> ::= <PredicateRelationalExpr>
!                 | <PredicateOperand> '=' <PredicateOperand>
!                 | <PredicateOperand> '!=' <PredicateOperand>


!<PredicateRelationalExpr> ::= <PredicateOperand> '<' <PredicateOperand>
!                 | <PredicateOperand> '<=' <PredicateOperand>
!                 | <PredicateOperand> '>' <PredicateOperand>
!                 | <PredicateOperand> '>=' <PredicateOperand>
<PredicateEquality> ::= <PredicateOperand> ComparableOperator <PredicateOperand>


<PredicateOperand> ::= <ObjectPath> 
		   | <Operand> 

<Operand> ::= String | Integer | Float | Date | Parameter | Boolean

<ObjectPath> ::=  <PathPart>
                | <PathPart> '/' <ObjectPath>

<PathPart> ::= Identifier
           | Identifier <Predicate>

! Check this
<ContainsExpr>::= 'CONTAINS' <ContainsOr>

<ContainsOr> ::= <ContainsAnd>
                 | <ContainsOr> 'OR' <ContainsAnd>

<ContainsAnd> ::= <ClassExpr>
                 | <ContainsAnd> 'AND' <ClassExpr>

<ClassExpr>::= <SimpleClassExpr>
               | '(' <SimpleClassExpr> <ContainsExpr> ')'
		 | <SimpleClassExpr> <ContainsExpr>

<SimpleClassExpr>::= <ArchetypedClassExpr>
		 | <VersionedClassExpr> 
		 | <VersionClassExpr> 
               
<ArchetypedClassExpr>::= Identifier
               | Identifier Identifier
               | Identifier <ArchetypePredicate>
               | Identifier Identifier <ArchetypePredicate>

!<VersioningClassExpr>::= <VersioningClass>
!               | <VersioningClass> Identifier
!               | <VersioningClass> <StandardPredicate>
!               | <VersioningClass> Identifier <StandardPredicate>

<VersionedClassExpr>::= 'VERSIONED_OBJECT'
               | 'VERSIONED_OBJECT' Identifier
               | 'VERSIONED_OBJECT' <StandardPredicate>
               | 'VERSIONED_OBJECT' Identifier <StandardPredicate>

<VersionClassExpr>::= 'VERSION'
               | 'VERSION' Identifier
               | 'VERSION' <StandardPredicate>
               | 'VERSION' Identifier <StandardPredicate>
		 | 'VERSION' <VersionPredicate>
               | 'VERSION' Identifier <VersionPredicate>

!<ArchetypedClass> ::= 'COMPOSITION' | 'OBSERVATION' | 'SECTION' | 'EVALUATION'
!             | 'INSTRUCTION' | 'ACTION'
             
! Example
! Note: 'select <Composition>' returns the Composition assocaited with the
! latest Version for that Versioned_Composition
!
! Select Top 20 BACKWARD c1|c2
! From EHR e[...] contains (Composition c1 contains (Observation o1 and Evaluation e)
!      or Observation o2) or Composition c2
! Where o1/Event/origin > ? and c1/contaxt/health_care_facility = ?
!       and c1/context/other_context[items[at0001] = ?
!       and e/contribution[uid=v/contribution/uid]/audit/commit_time < ?
! Order by c1/context/start_time